#**********************************************************************************
#
# Een voorbeeld hoe eigen logjes in een html pagina in te bouwen
#
#**********************************************************************************
$Owner = "GeoFlowers"                        # hier uw eigen aka invullen
$file = $_Install + "\temp\Htmlvanus.html"   # Hier komt de output te staan
$images = $_Install + "\images"              # GSAK images staan hier
$images = replace("\","/",$images,false)     # HTML Slash en backslash goed zetten
$curdb = $_CurrentDatabase                   # huidige database vastleggen
DATABASE Name="test" Action=select	         # Deze bestaande! database selecteren
$html = $header                              # Begin regels van de HTML output
SORT by="FoundbyMe" sequence=D        # sorteren op found, laatst gevonden bovenaan  

While not($_EOL)
  While not($_EOL)
    if $d_FoundByMeDate > [00000000]  # als record met een found
      # cache type image
      $html = $html + "<h3>" +"<img src=" + quote($images + "\cache" + $d_CacheType + ".gif") 
      $html = $html + "alt="  + quote($d_CacheType) + " >"   
      # cache name / placed by line
      $html = $html +  $d_name + " by " + $d_PlacedBy + " ($d_difficulty/$d_Terrain) </h3>"
      # set the Url to click on to go online
      if not (isempty($d_url))
        $html = $html + "(<a href=" + quote($d_Url) + ">" + $d_Code + "</a>)" + $_NewLine
      EndIf
      # *******************************************************************
      # Nu de logjes, hier begint het zoeken per cache naar eigen logjes
      # Er wordt gebruik gemaakt van andere tabellen! 
      # *******************************************************************
        GoSub Name=Logs   # Hier wordt een andere tabel actief!
      # Terug van de tabel Logs, de gewenste Tabel weer activeren  
        Table active=Caches
      # Inhoud van de log aan de html code toevoegen  
        $Html = $Html + $logs + "<br /><hr />"
      endif
    goto position=next   # volgende record
    EndWhile  
  goto position=next # volgende record tot 1e record met een found
EndWhile  

# *******************************************************************************
# alle caches uit de database zijn nu gepasseerd Html nu afsluiten
# *******************************************************************************
$html = $html + $footer + $_NewLine	
$error = Putfile($file,$html)
FileOpen File="$file"

#********************************************************************************
# tot besluit nog even de standaard db aktiveren
DATABASE Name=$curdb   Action=select	# Deze database is hiermee nu geselecteerd
#********************************************************************************

BeginSub name=Logs
  Table Active=Logs scope=Parent
  $logs = ""
  If $_count > 0
    $temp = ""
    While not ($_eol)
      GoSub Name=LogImage 
      if $d_lBy = $Owner
        $temp = $temp + "<p>" + "<img src=" + quote($LogImage) + " width=" + quote("15") + " height=" + quote("15") +  " alt=" + quote($d_lType) + ">" 
        $temp = $temp + "&nbsp;<b>" + DateFormat($d_lDate) + " by&nbsp;" + $d_lBy + "</b><br>" + $_NewLine
        $HtmlText = $d_lText
        GoSub Name=HtmlText
        $temp = $temp + $HtmlText + $_NewLine
      endif  
      Goto Position=Next
    EndWhile
    $Logs = $temp 
  EndIf
EndSub

BeginSub Name=LogImage
 # debug status=on
  $logImage = extract($LogTypes,$d_lType + "=",2)
  If IsEmpty($logImage)
    $logImage = "Note"
  Else
    $logImage = extract($LogImage,$_Newline,1)
  EndIf
  $LogImage = $Images + "/log" + $LogImage + ".gif"
EndSub

BeginSub name=HtmlText
  $HtmlText = Replace("<br>", "~.~", $HtmlText, true) # exception, do not replace <br>
  $HtmlText = Replace("&", "&amp;", $HtmlText, false)
  $HtmlText = Replace("<","&lt;", $HtmlText, false)
  $HtmlText = Replace(">", "&gt;", $HtmlText, false)
  $HtmlText = Replace($_quote, "&quot;", $HtmlText, false)
  $HtmlText = Replace("~.~", "<br>", $HtmlText, false)
  $HtmlText = Replace($_Newline,"<br>",$HtmlText,false) 
EndSub

# de html opmaak
<data> VarName=$header
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN" "http://www.w3.org/TR/html4/loose.dtd">
<html>
<head>
<title>GSAK Offline</title>
<style type='text/css'>                                                 
div h3 { font-weight: bold; font-size: 16px; color: #CC3300; background-color: #EEEEEE } 
div p  { font-weight: normal; font-size: 12px; color: #000000; }
.logs { width: 440px;
        margin: 0px 150px 0px 286px;
        border: 2px solid #33FF00;
        padding: 5px;
        top:4px; }
</style>
</head>                                                                
<body>
<div class="logs">
<enddata> 

<data> VarName=$footer
</table>
</div>
</body>
</html>
<enddata>

<data> VarName=$LogTypes
Webcam Photo Taken=Webcam
Found it=Found
Didn't find it=NotFound
Temporarily Disable Listing=Disable
Archive (show)=Archived
Archive (no show)=Archived
Needs Archived=NeedsArchived
Post Reviewer Note=Review
Will Attend=WillAttend
Enable Listing=Enable
Publish Listing=Published
Owner Maintenance=OwnerMaintenance
Needs Maintenance=NeedsMaintenance
Update Coordinates=UpdateCoordinates
Attended=Attended
<enddata>